Explorerdaten

[Wale]

Ist es möglich eine ganze Verzeichnissstruktur mit Datennahme, Grösse, Typ und Datum in eine Excel Tabelle zu überführen.

Vielen Dank für eine Hilfe!

 

[froeschli]

Du könntest es über Umwege machen... In der Konsole (Start > Ausführen > cmd) den Befehl

dir /s > C:\Verzeichnis.txt

eingeben. Dies erstellt dir im Laufwerk C:\ die eine Textdatei namens Verzeichnis.txt, welche du wiederum in Excel importieren kannst....

Das ganze ist etwas "von Hand" aber wenn es eine einmalige Sache ist, sollte das innerhalb von 20 Minuten machbar sein...

Gruss froeschli

 

[Thomas Ramel]

Grüezi Wale

Du kannst das Gnaze auch automatisiert mit VBA tun; die folgenden Zeilen listen das Verzeichnis der Wahl im ersten Tabellenblatt der aktiven Mappe auf:

Option Explicit

Public Sub AufrufVerzeichnis()
'Generiert das Folder-Objekt für den Verzeichnisbaum
'Verweis auf die 'Microsoft Scripting Runtime' setzen
Dim fso As New FileSystemObject
Dim fld As Folder
    Set fld = fso.GetFolder("D:\Test")
    Verzeichnisbaum fld
End Sub

Public Sub Verzeichnisbaum(fld As Folder, Optional i As Long = 0)
'Listet alle Unterverzeichnisse und Dateien eines Startverzeichnisses auf
'Der Aufruf erfolgt rekursiv, daher die Aufruf-Sub mit Parameter
Dim subfld As Folder, Flag As Boolean, fil As file
   Flag = True
   For Each fil In fld.Files
      If Flag Then Worksheets(1).Range("A1").Offset(i, 0) = _
         fil.ParentFolder.Path
      Worksheets(1).Range("A1").Offset(i, 1) = fil.Name
      Worksheets(1).Range("A1").Offset(i, 2) = fil.DateCreated
      i = i + 1
      Flag = False    'dient dazu, den Pfad nicht jedesmal zu schreiben
   Next
   For Each subfld In fld.SubFolders
      Verzeichnisbaum subfld, i
   Next
End Sub

 

[Officer]

Falls ein Kompilierungsfehler auftritt: Es muss in den Verweisen noch "Microsoft Scripting Runtime" (c:\Windows\system32\scrrun.dll) aktiviert sein.

 

[Thomas Ramel]

Grüezi Officer

Das ist richtig; diesen Hinweis hatte ich vergessen.

Danke für den Nachtrag!

 

[Officer]

Hallo Thomas

Ich bin an Verweisen schon schier verzweifelt, deshalb möchte ich das anderen gern ersparen...

 

[froeschli]

@Thomas und Officer:
Danke für diesen Skript! Damit geht es natürlich viel einfacher, als die Lösung von Hand.

Gruss froeschli